mapnik/plugins/input/shape/SConscript

	
# This file is part of Mapnik (c++ mapping toolkit)
#
# Copyright (C) 2006 Artem Pavlenko, Jean-Francois Doyon
#
# Mapnik is free software; you can redistribute it and/or
# modify it under the terms of the GNU Lesser General Public
# License as published by the Free Software Foundation; either
# version 2.1 of the License, or (at your option) any later version.
#
# This library is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
# Lesser General Public License for more details.
#
# You should have received a copy of the GNU Lesser General Public
# License along with this library; if not, write to the Free Software
# Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
#
# $Id$


Import ('env')

prefix = env['PREFIX']
install_prefix = env['DESTDIR'] + '/' + prefix

plugin_env = env.Clone()

shape_src = Split(
	"""
        dbffile.cpp
        shape.cpp
        shape_featureset.cpp
        shape_index_featureset.cpp
        shape_io.cpp
	"""
        )

libraries = ['boost_iostreams%s' % env['BOOST_APPEND']]    

if env['PLATFORM'] == 'Darwin':
    libraries.append('mapnik2')
    libraries.append(env['ICU_LIB_NAME'])
    libraries.append('boost_system%s' % env['BOOST_APPEND'])
    libraries.append('boost_filesystem%s' % env['BOOST_APPEND'])

if env['SHAPE_MEMORY_MAPPED_FILE']:
    plugin_env.Append(CXXFLAGS = '-DSHAPE_MEMORY_MAPPED_FILE')

input_plugin = plugin_env.SharedLibrary('../shape', SHLIBSUFFIX='.input', source=shape_src, SHLIBPREFIX='', LIBS = libraries, LINKFLAGS=env['CUSTOM_LDFLAGS'])

if env['PLATFORM'] == 'Darwin':
    # if the plugin links to libmapnik2 ensure it is built first
    Depends(input_plugin,'../../../src/libmapnik2.dylib')

if 'uninstall' not in COMMAND_LINE_TARGETS:
    env.Install(install_prefix + '/' + env['LIBDIR_SCHEMA'] + env['LIB_DIR_NAME'] + '/input', input_plugin)
    env.Alias('install', install_prefix + '/' + env['LIBDIR_SCHEMA'] + env['LIB_DIR_NAME'] + '/input')