From e31578045ed0ff2b81955d7a364a67633beb2909 Mon Sep 17 00:00:00 2001
From: Mickey Rose <mickey.rose@seznam.cz>
Date: Sat, 30 Jun 2018 03:12:06 +0200
Subject: [PATCH] add script for auto-generating links in CHANGELOG

[skip ci]
---
 scripts/markdown-hyperlinks.pl | 49 ++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100755 scripts/markdown-hyperlinks.pl

diff --git a/scripts/markdown-hyperlinks.pl b/scripts/markdown-hyperlinks.pl
new file mode 100755
index 000000000..a09b94e38
--- /dev/null
+++ b/scripts/markdown-hyperlinks.pl
@@ -0,0 +1,49 @@
+#! /usr/bin/env perl
+#
+#   Re-generate hyperlinks in place:
+#
+#       perl -i scripts/markdown-hyperlinks.pl CHANGELOG.md
+#
+#   Generate to another file:
+#
+#       scripts/markdown-hyperlinks.pl CHANGELOG.md > CHANGELOG-autolink.md
+
+use strict;
+use warnings;
+
+my $user = qr/ [a-zA-Z] [a-zA-Z0-9]* /x;
+my $repo = qr/ [a-zA-Z] [a-zA-Z0-9.-]* /x;
+
+while (<>) {
+
+    # make links from @username references
+    # (except when escaped like \@foobar or `@foobar`)
+    s;(?<! \[ | \\ | \` ) \@ ($user) \b (?! \] )
+     ;[\@$1](https://github.com/$1);xg;
+
+    # make links from #1234 references (except when escaped like \#5)
+    # we can't tell whether the number refers to an issue or a pull request,
+    # luckily link to issues/1234 works in either case
+    s;(?<! \[ | \\ ) \# ([0-9]+) \b (?! \] )
+     ;[\#$1](https://github.com/mapnik/mapnik/issues/$1);xg;
+
+    # make links from commit hashes
+    # (accept 7 or 9-40 hex digits, but not 8 which could be a date)
+    s;(?<! \[ | / ) \b (([0-9a-f]{7})([0-9a-f]{2,33})?) \b (?! \] )
+     ;[$2](https://github.com/mapnik/mapnik/commit/$1);xg;
+
+    # make shortcut links from raw URIs (which GFM turns into proper links,
+    # but doesn't contract even though it could)
+    # - issues
+    s;(?<! \] \( ) (https://github\.com/mapnik/mapnik/(?:issues|pull)/([0-9]+))
+     ;[\#$2]($1);xg;
+    s;(?<! \] \( ) (https://github\.com/($user/$repo)/(?:issues|pull)/([0-9]+))
+     ;[$2\#$3]($1);xg;
+    # - commit hashes
+    s;(?<! \] \( ) (https://github\.com/mapnik/mapnik/commit/([0-9a-f]{7})[0-9a-f]{0,33}) \b
+     ;[$2]($1);xg;
+    s;(?<! \] \( ) (https://github\.com/($user/$repo)/commit/([0-9a-f]{7})[0-9a-f]{0,33}) \b
+     ;[$2\@$3]($1);xg;
+
+    print;
+}